CLEO Help Combining interior cleo

[Deraidos]

I made two cleo scripts for my friend's SAMP interior mod. It spawns an entrance marker and invisible sphere so players can enter and exit.

Spoiler: Entrance script

{$CLEO .cs}
//-------------MAIN---------------
thread 'nongsind'
0A40: 1@ = create_entrance_marker_at -2571.38 318.60 10.56 color 14
:rmhdito_42
wait 0
if
Player.Defined($PLAYER_CHAR)
jf @rmhdito_42
if
00FF: actor $PLAYER_ACTOR sphere 0 in_sphere -2571.38 318.60 10.56 radius 1.0 1.0 1.0 on_foot
jf @rmhdito_42
wait 500
select_interior 1
04E4: refresh_game_renderer_at -2677.85 1369.77
0860: link_actor $PLAYER_ACTOR to_interior 1
Actor.PutAt($PLAYER_ACTOR, -2674.40, 1370.07, 906.84)
0ACC: show_text_lowpriority "Teleported to Tempat Nongkrong IND" time 1000
jump @rmhdito_42

Spoiler: Exit script

{$CLEO .cs}
//-------------MAIN---------------
thread 'nongsind'
0A40: 1@ = create_entrance_marker_at -2675.95 1369.89 906.84 color 14
:rmhdito_44
wait 0
if
Player.Defined($PLAYER_CHAR)
jf @rmhdito_44
if
00FF: actor $PLAYER_ACTOR sphere 0 in_sphere -2675.95 1369.89 906.84 radius 1.0 1.0 1.0 on_foot
jf @rmhdito_44
wait 500
select_interior 0
04E4: refresh_game_renderer_at -2571.39 317.06
0860: link_actor $PLAYER_ACTOR to_interior 0
Actor.PutAt($PLAYER_ACTOR, -2571.41, 320.12, 10.56)
0ACC: show_text_lowpriority "Teleported to IND Base" time 1000
jump @rmhdito_44

But when I combine them, only the entrance works. How do I make it into one cleo?

 

[Krc]

if
00FF: actor $PLAYER_ACTOR sphere 0 in_sphere -2571.38 318.60 10.56 radius 1.0 1.0 1.0 on_foot
Then
// your script
else
if
00FF: actor $PLAYER_ACTOR sphere 0 in_sphere -2675.95 1369.89 906.84 radius 1.0 1.0 1.0 on_foot
Then
// your script
end
end

{$CLEO .cs}
0000: NOP
REPEAT
Wait 0
Until 0256: player $PLAYER_CHAR defined

0A40: 1@ = create_entrance_marker_at -2571.38 318.60 10.56 color 14

While True
Wait 0
If
0256: player $PLAYER_CHAR defined
Then
If
00FF: actor $PLAYER_ACTOR sphere 0 in_sphere -2571.38 318.60 10.56 radius 3.0 3.0 3.0 on_foot
Then
wait 500 
select_interior 1
04E4: refresh_game_renderer_at -2677.85 1369.77
0860: link_actor $PLAYER_ACTOR to_interior 1
00A1: put_actor $PLAYER_ACTOR at -2674.40 1370.07 906.84
0ACC: show_text_lowpriority "Teleported to Tempat Nongkrong IND" time 1000
else
If
00FF: actor $PLAYER_ACTOR sphere 0 in_sphere -2675.95 1369.89 906.84 radius 3.0 3.0 3.0 on_foot
Then
wait 500
select_interior 0
04E4: refresh_game_renderer_at -2571.39 317.06
0860: link_actor $PLAYER_ACTOR to_interior 0
00A1: put_actor $PLAYER_ACTOR at -2571.41 320.12 10.56
0ACC: show_text_lowpriority "Teleported to IND Base" time 1000
end
end    
end
END