CLEO Help Player Coord

[mrT101]

I am trying to make a cleo which shows other players on the server's coordinates. I am using

20@ = 0 (Earlier in the code)

:J_10

20@ += 1 

if
SAMP.IsPlayerConnected(20@)
else_jump @J_10
SAMP.GetStreamedOutPlayerPos(20@, 1@, 2@, 3@)   

but it only will show my coordinates. Any Suggestions?

 

[blackHat]

Hmmm it should show others

If 20@ is a var. Of handle of player you already made a command for
Like /get 5
So here the id is  5
You have to say 20@ = id 5 player handler or something like that

It's looks like u didn't add that

 

[ThermaL]

Here's my script:

Spoiler

{$CLEO}

0662: "LEL"

0B34: samp register_client_command "getcoords" to_label @cmd
31@ = false

:get_player_coords
wait 0
if
31@ == true
jf @get_player_coords
Actor.StorePos(3@, 5@, 6@, 7@)
0AF8: samp add_message_to_chat "Player: %s, ID: %d | Coords, X: %0.1f Y: %0.1f Z: %0.1f" color 0x50E18F 4@ 2@ 5@ 6@ 7@
31@ = false
SAMP.CmdRet
goto @get_player_coords

:get_streamed_out_player_pos
wait 0
SAMP.GetStreamedOutPlayerPos(2@, 8@, 9@, 10@)
0AF8: samp add_message_to_chat "Player: %s, ID: %d | Coords, X: %0.1f Y: %0.1f Z: %0.1f" color 0x50E18F 4@ 2@ 8@ 9@ 10@
SAMP.CmdRet
jump @get_player_coords

:cmd
wait 0
SAMP.IsCommandTyped(0@)
if
0AD4: 1@ = scan_string 0@ format "%d" 2@
jf @usage
if
SAMP.IsPlayerConnected(2@)
jf @invalid
3@ = SAMP.GetActorHandleByPlayerID(2@)
4@ = SAMP.GetPlayerNickname(2@)
if
056D:  actor 3@ defined
jf @get_streamed_out_player_pos
31@ = true
SAMP.CmdRet
goto @get_player_coords

:usage
wait 0
0AF8: samp add_message_to_chat "USAGE: /getcoords <ID>" color 0xBFBFBF
SAMP.CmdRet
jump @get_player_coords

:invalid
wait 0
0AF8: samp add_message_to_chat "Invalid ID" color 0xBF0000
SAMP.CmdRet
jump @get_player_coords